代码拉取完成,页面将自动刷新
import static org.gradle.kotlin.dsl.KotlinDependencyExtensionsKt.embeddedKotlinVersion
buildscript {
ext.kotlin_version = embeddedKotlinVersion
repositories {
mavenLocal()
google()
mavenCentral()
jcenter()
maven { url 'https://plugins.gradle.org/m2/' }
}
dependencies {
classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.21.2"
classpath "de.marcphilipp.gradle:nexus-publish-plugin:0.4.0"
classpath "io.johnsonlee.buildprops:buildprops-gradle-plugin:1.0.0"
}
}
apply plugin: 'io.codearte.nexus-staging'
allprojects { project ->
apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'de.marcphilipp.nexus-publish'
group = 'com.didiglobal.booster'
version = '1.6.0'
repositories {
mavenLocal()
google()
mavenCentral()
jcenter()
}
javadoc {
failOnError = false
}
task packageJavadoc(type: Jar) {
classifier = 'javadoc'
from javadoc
}
task packageSources(type: Jar) {
classifier = 'sources'
from sourceSets.main.allSource
}
artifacts {
archives packageJavadoc, packageSources
}
test {
testLogging {
events "passed", "skipped", "failed", "standardOut", "standardError"
}
}
nexusPublishing {
repositories {
sonatype {
username = OSSRH_USERNAME
password = OSSRH_PASSWORD
}
}
}
publishing {
publications {
mavenJava(MavenPublication) {
groupId = project.group
artifactId = project.name
version = project.version
from components.java
artifact project.packageSources {
classifier "sources"
}
artifact project.packageJavadoc {
classifier "javadoc"
}
pom {
name = project.name
url = 'https://github.com/didi/booster'
description = project.description ?: project.name
scm {
connection = 'scm:git:git://github.com/didi/booster.git'
developerConnection = 'scm:git:git@github.com:didi/booster.git'
url = 'https://github.com/didi/booster'
}
licenses {
license {
name = 'Apache License'
url = 'https://www.apache.org/licenses/LICENSE-2.0'
}
}
}
pom.withXml { xml ->
(['git', 'log', '--format=%aN %aE'].execute() | ['sort', '-u'].execute()).with {
waitForOrKill(5000)
if (0 == exitValue()) {
def developers = xml.asNode().appendNode('developers')
text.eachLine { line ->
def sp = line.lastIndexOf(' ')
if (sp > 0) {
def id = line.substring(0, sp).trim()
def email = line.substring(sp + 1).trim()
developers.appendNode('developer').with {
appendNode('id', id)
appendNode('email', email)
}
}
}
}
}
}
}
}
}
signing {
sign publishing.publications.mavenJava
}
}
subprojects { project ->
rootProject.clean.dependsOn project.clean
}
dependencies {
implementation project(':booster-gradle-plugin')
}
nexusStaging {
packageGroup = "com.didiglobal"
username = OSSRH_USERNAME
password = OSSRH_PASSWORD
numberOfRetries = 50
delayBetweenRetriesInMillis = 3000
}
此处可能存在不合适展示的内容,页面不予展示。您可通过相关编辑功能自查并修改。
如您确认内容无涉及 不当用语 / 纯广告导流 / 暴力 / 低俗色情 / 侵权 / 盗版 / 虚假 / 无价值内容或违法国家有关法律法规的内容,可点击提交进行申诉,我们将尽快为您处理。